您正在查看: 标签 应用程序 下的文章

MailMergeWizardSendToCustom 事件

MailMergeWizardSendToCustom 事件

在“邮件合并向导”的步骤六中单击自定义按钮时,该事件发生。

Private Sub object_MailMergeWizardSendToCustom(ByVal Doc As Document)

object 在类模块事件中声明的 Application 类型对象。有关使用 Application 对象事件的详细信息,请参阅使用 Application 对象事件。

Doc 邮件合并主文档。

说明

使用 ShowSendToCustom 属性在“邮件合并向导”的步骤六中创建一个自定义按钮。

示例

该示例在用户单击自定义目标按钮时,执行到传真机的合并。该示例假定用户可以访问自定义目标按钮,数据源中每一条记录包含传真号码,并且声明了一个名为 MailMergeApp 的应用程序变量,并将 Word Application 对象赋给该变量。

Private Sub MailMergeApp_MailMergeWizardSendToCustom(ByVal Doc As Document)
    With Doc.MailMerge
        .Destination = wdSendToFax
        .Execute
    End With
End Sub

MailMergeDataSourceValidate 事件

MailMergeDataSourceValidate 事件

当用户通过单击“邮件合并收件人”对话框中的“验证有效性”执行地址验证时,该事件发生。

Private Sub object_MailMergeDataSourceValidate(ByVal Doc As Document, Handled As Boolean)

object 在类模块事件中声明的 Application 类型对象。有关使用 Application 对象事件的详细信息,请参阅使用 Application 对象事件。

Doc 邮件合并主文档。

Handled 如果该参数值为 True,则对邮件合并数据源运行伴随的验证代码。如果该参数值为 False,则取消数据源验证。

说明

如果未在计算机上安装地址验证软件,MailMergeDataSourceValidate 事件允许您创建简单的筛选例程,例如循环查找记录以检查邮政编码,并删除任何非美国的邮政编码。美国以外的用户可以通过更改以下代码示例和使用 Microsoft Visual Basic 命令搜索文本或特殊字符,筛选出所有的美国邮政编码。

示例

该示例显示一条消息,询问是否验证数据源中的地址。该示例假定邮政编码为美国邮政编码,并且在一般声明中声明了一个名为 MailMergeApp 的应用程序变量,并将 Word Application 对象赋给该变量。(您可以更改该示例,以筛选国际邮政编码或其他具有附加的 4 位数字定位代码的邮政编码)

Private Sub MailMergeApp_MailMergeDataSourceValidate(ByVal Doc As Document, _
        Handled As Boolean)
Dim intCount As Integer

Handled = True

On Error Resume Next

With Doc.MailMerge.DataSource

    'Set the active record equal to the first record in the data source
    .ActiveRecord = wdFirstRecord
    Do
        intCount = intCount + 1

        'Set the condition that field six must be greater than or
        'equal to five
        If Len(.DataFields(6).Value) < 5 Then

            'Exclude the record if field six is less than five digits
            .Included = False

            'Mark the record as containing an invalid address field
            .InvalidAddress = True

            'Specify the comment attached to the record explaining
            'why the record was excluded from the mail merge
            .InvalidComments = "The zip code for this record is " _
                & "less than five digits. It will be removed " _
                & "from the mail merge process."

        End If

        'Move the record to the next record in the data source
        .ActiveRecord = wdNextRecord

    'End the loop when the counter variable
    'equals the number of records in the data source
    Loop Until intCount = .RecordCount
End With

End Sub

WizardState 属性

WizardState 属性

返回或设置一个 Long 类型的数值,代表文档“邮件合并向导”当前的步骤。WizardState 方法返回一个与当前“邮件合并向导”步骤相同的数值;如果返回零(0),则表示“邮件合并向导”已经关闭。可读写。

expression.WizardState

expression 必需。该表达式返回“应用于”列表中的一个对象。

示例

本示例检查活动文档当是否已显示“邮件合并向导”,如果是,则跳转至“邮件合并向导”的第六步并从“邮件合并向导”中删除第五步。

Sub ShowMergeWizard()
    With ActiveDocument.MailMerge
        If .WizardState > 0 Then
            .ShowWizard InitialState:=6, ShowPreviewStep:=False
        End If
    End With
End Sub

WindowState 属性

WindowState 属性

该属性返回或设置指定的文档窗口或任务窗口的状态。WdWindowState,可读写。

WdWindowState 可以是下列 WdWindowState 常量之一:
wdWindowStateMaximize
wdWindowStateNormal
wdWindowStateMinimize

expression.WindowState

expression 必需。该表达式返回“应用于”列表中的一个对象。

说明

wdWindowStateNormal 常量指明窗口没有最大化或最小化。不能设置非活动窗口的状态。在设置窗口状态之前可用 Activate 方法激活窗口。

示例

如果活动窗口不是最大化或最小化状态,本示例将其最大化。

If ActiveDocument.ActiveWindow _
    .WindowState = wdWindowStateNormal Then _
    ActiveDocument.ActiveWindow.WindowState = wdWindowStateMaximize

本示例最小化 Microsoft Excel 应用程序窗口。

For Each myTask In Tasks
    If InStr(myTask.Name, "Microsoft Excel") > 0 Then
        myTask.Activate
        myTask.WindowState = wdWindowStateMinimize
    End If
Next myTask

WindowSize 事件

WindowSize 事件

移动应用程序窗口或调整其大小时,该事件发生。

Private Sub object_WindowSize(ByVal Doc As Document, ByVal Wn As Window)

object 在类模块事件中声明的 Application 类型对象。有关使用 Application 对象事件的详细信息,请参阅使用 Application 对象事件。

Doc 调整其大小的窗口中的文档。

Wn 调整其大小的窗口。

示例

该示例在任何时刻移动 Microsoft Word 应用程序窗口或调整其大小时,显示一条消息。该示例假定在一般声明中声明了一个名为“WordApp”的应用程序变量,并将 Word Application 对象赋给该变量。

Private Sub WordApp_WindowSize(ByVal Doc As Document, _
        ByVal Wn As Window)
    MsgBox "You have just resized or moved your window."
End Sub